Quickstart: Creating Charts

One of the compelling features of R is its ability to create beautiful charts. With the R Type Provider, you can use all of R capabilities from F#, and create simple charts quickly to explore and visualize your data on-the-fly, as well as generate publication quality graphics that can be exported to virtually any format.

Charts Basics

Basic charts can be found in the graphics package. Assuming you installed the R Type Provider in your project from NuGet, you can reference the required libraries and packages this way:

1: 
2: 
3: 
4: 
5: 
6: 
7: 

#I "../packages/RProvider.1.0.11"
#load "RProvider.fsx"

open System
open RDotNet
open RProvider
open RProvider.graphics

Once the libraries and packages have been loaded, producing basic charts is as simple as this:

 1: 
 2: 
 3: 
 4: 
 5: 
 6: 
 7: 
 8: 
 9: 
10: 
11: 
12: 

let widgets = [ 3; 8; 12; 15; 19; 18; 18; 20; ]
let sprockets = [ 5; 4; 6; 7; 12; 9; 5; 6; ]

R.plot(widgets)

R.plot(widgets, sprockets)

R.barplot(widgets)

R.hist(sprockets)

R.pie(widgets)

Exporting and Saving Charts

Charts can be exported and saved to various formats; once you have opened the grDevices package, you can save a chart like this:

 1: 
 2: 
 3: 
 4: 
 5: 
 6: 
 7: 
 8: 
 9: 
10: 
11: 
12: 
13: 
14: 

// Required package to save charts
open RProvider.grDevices

// Create path to an image testimage.png on the Desktop
let desktop = Environment.GetFolderPath(Environment.SpecialFolder.Desktop)  
let path = desktop + @"\testimage.png"

// Open the device and create the file as a png.
// R.bmp, R.jpeg, R.pdf, ... will generate other formats.
R.png(filename=path, height=200, width=300, bg="white")
// Create the chart into the file
R.barplot(widgets)
// Close the device once the chart is complete
R.dev_off ()

Advanced Charts Options

The graphic functions exposed by the R Type Provider come in two flavors; they either have optional named arguments, followed by a ParamArray for extended arguments, or they take named parameters, an IDictionary which contains all the arguments passed to the function.

Named Arguments

Consider for instance the following example:

1: 
2: 

R.barplot(widgets)
R.title(main="Widgets", xlab="Period", ylab="Quantity")

R.title has 2 signatures, one of them with optional arguments, demonstrated above to set the main title as well as the labels for the x and y axis, ignoring some of the other available options. You can see another example in the previous section in the R.png call.

Named Parameters

Named parameters allow you to specify every argument supported by R, as an IDictionary of string, object. The string is the name of the argument, and the object its value.

Finding the available arguments for a R function can be tricky; the full list of arguments can usually be found in the R developer documentation, navigating in the correct package. For instance, R.plot belongs to graphics, and can be found here.

The easiest way to use that feature is to leverage the built-in function namedParams, like in this example:

 1: 
 2: 
 3: 
 4: 
 5: 
 6: 
 7: 
 8: 
 9: 
10: 
11: 
12: 
13: 
14: 

R.plot(
    namedParams [   
        "x", box widgets; 
        "type", box "o"; 
        "col", box "blue";
        "ylim", box [0; 25] ])

R.lines(
    namedParams [   
        "x", box sprockets; 
        "type", box "o"; 
        "pch", box 22;
        "lty", box 2;
        "col", box "red" ])

The first call specifies what to plot (widgets), what type of line to use, the color, and the scale of the axis. The second call adds sprockets, specifying lty (the line type), and pch (the plotting character).

box is used to reduce all elements to objects, so that the lists have consistent types.

A possibly more elegant way to use namedParams is to follow the pattern below:

 1: 
 2: 
 3: 
 4: 
 5: 
 6: 
 7: 
 8: 
 9: 
10: 
11: 
12: 
13: 
14: 

namedParams [   
    "x", box widgets; 
    "type", box "o"; 
    "col", box "blue";
    "ylim", box [0; 25] ]
|> R.plot

namedParams [   
    "x", box sprockets; 
    "type", box "o"; 
    "pch", box 22;
    "lty", box 2;
    "col", box "red" ]
|> R.lines

• R Type Provider
• Home page
• Get Library via NuGet
• Source Code on GitHub
• License (BSD)
• Release Notes
• Bug reports & feature requests
• Documentation
• R provider on Mac/Linux
• Statistics walkthrough
• Charting walkthrough
• Reading and writing RData
• Passing data between F# and R
• Analysing stock prices
• R packages & naming
• Reference
• API Reference
• Internals
• Developer notes
• Diagnostics & debugging
• Whats and whys
• How does it work